blob: ab04890e3136e6c20bb5aae02381f29043d60094 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id$
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Marti Raudsepp <marti@juffo.org>
# Contributor: Radu Andries <admiral0@tuxfamily.org>
# Contributor: Andy Weidenbaum <archbaum@gmail.com>
# Mantainer: Lorenzo Ferrillo <lorenzofer at live dot it>
_pkgname=zbar
pkgname=lib32-zbar
pkgver=0.23.1
pkgrel=3
pkgdesc="Application and library for reading bar codes from various sources. 32bit libraries only version"
arch=('x86_64')
url="https://github.com/procxx/zbar"
license=('LGPL')
depends=('zbar' 'lib32-v4l-utils' 'lib32-dbus' 'lib32-libsm' 'lib32-libxv')
makedepends=('docbook-xsl' 'xmlto')
source=("$_pkgname-$pkgver.tar.gz::https://github.com/mchehab/zbar/archive/$pkgver.tar.gz" "configure.patch")
sha256sums=('297439f8859089d2248f55ab95b2a90bba35687975365385c87364c77fdb19f3' '4b6bd83d5923aed8ac34ff088340a65514bcff0a345dc6acd08e348e72744702')
prepare() {
cd zbar-$pkgver
patch -i ${srcdir}/configure.patch configure.ac
autoreconf -vfi
}
build() {
cd zbar-$pkgver
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
#export PYTHON='/usr/bin/python2-32'
#export PYTHON_CONFIG='/usr/bin/python2-32-config'
#PKG_CONFIG_PATH="/usr/lib32/imagemagick6/pkgconfig"
./configure --prefix=/usr --libdir=/usr/lib32 --without-python --without-qt --without-gtk --without-imagemagick --without-java CFLAGS="$CFLAGS -DNDEBUG"
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd zbar-$pkgver
make DESTDIR="$pkgdir" install
rm -Rf "$pkgdir"/usr/lib32/*.a \
"$pkgdir"/usr/include/ \
"$pkgdir"/usr/bin \
"$pkgdir"/usr/share \
"$pkgdir"/etc
}
|