blob: fbe5f575513e00c3df2ecbb609f5520a97d93652 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Previous maintainer: Jakob Gahde <j5lx@fmail.co.uk>
pkgname=libarchive-git
pkgver=3.6.2.r19.gaa091636
pkgrel=1
pkgdesc="Multi-format archive and compression library"
arch=('i686' 'x86_64')
url="https://libarchive.org/"
license=('BSD' 'custom')
depends=('glibc' 'acl' 'attr' 'bzip2' 'expat' 'lz4' 'openssl' 'xz' 'zlib' 'zstd')
makedepends=('git')
provides=("libarchive=$pkgver")
conflicts=('libarchive')
options=('staticlibs')
source=("git+https://github.com/libarchive/libarchive.git")
sha256sums=('SKIP')
pkgver() {
cd "libarchive"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "libarchive"
build/autogen.sh
./configure \
--prefix="/usr" \
--without-nettle \
--without-xml2
make
}
check() {
cd "libarchive"
make check
}
package() {
cd "libarchive"
make DESTDIR="$pkgdir" install
install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/libarchive"
}
|