blob: 8692e54dca0a57f87deda48ce0939b8aef5dd81a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=libbacktrace-git
pkgver=r124.gb9e4006
pkgrel=1
pkgdesc="Library to produce symbolic backtraces"
arch=('i686' 'x86_64')
url="https://github.com/ianlancetaylor/libbacktrace"
license=('BSD-3-Clause')
depends=('glibc' 'libgcc' 'zlib')
makedepends=('git' 'libunwind')
provides=("libbacktrace=$pkgver" 'libbacktrace.so')
conflicts=('libbacktrace')
options=('staticlibs')
source=("git+https://github.com/ianlancetaylor/libbacktrace.git"
"add_pkg-config_file.patch::https://patch-diff.githubusercontent.com/raw/ianlancetaylor/libbacktrace/pull/92.patch")
sha256sums=('SKIP'
'680dbbf1db9953d4aeef2205274d2c3672d150a106f782c368d628623173dd1f')
prepare() {
cd "libbacktrace"
patch -Np1 -i "$srcdir/add_pkg-config_file.patch"
}
pkgver() {
cd "libbacktrace"
_rev=$(git rev-list --count --all)
_hash=$(git rev-parse --short HEAD)
printf "r%s.g%s" "$_rev" "$_hash"
}
build() {
cd "libbacktrace"
autoreconf -fi
CFLAGS="$CFLAGS -ffat-lto-objects" \
./configure \
--prefix="/usr" \
--enable-shared \
--with-system-libunwind
make
}
check() {
cd "libbacktrace"
#make check
}
package() {
cd "libbacktrace"
make DESTDIR="$pkgdir" install
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/libbacktrace"
}
|