summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6c77e062a05fafc83b8fc2bab9578a861c0ba08a (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgname=libbluray-git
pkgver=1.1.1.14.g38bbd8e8
pkgrel=1
pkgdesc="Library to access Blu-Ray disks for video playback. (GIT version)"
arch=('x86_64')
license=('LGPL2.1')
url='http://www.videolan.org/developers/libbluray.html'
depends=('libxml2'
         'fontconfig'
         'libfreetype.so'
         )
makedepends=('git'
             'apache-ant'
             'classpath'
             'java-environment<=11'
             )
optdepends=('libaacs: Enable AACS decryption'
            'java-runtime<=11: BD-J library'
            )
provides=('libbluray'
          'libbluray.so'
          )
conflicts=('libbluray')
source=('git+https://code.videolan.org/videolan/libbluray.git'
        'git+https://code.videolan.org/videolan/libudfread.git'
        )
sha256sums=('SKIP'
            'SKIP'
           )

pkgver() {
  cd libbluray
  echo "$(git describe --long --tags | tr - .)"
}

prepare() {
  mkdir -p build

  export JDK_HOME="/usr/lib/jvm/java-11-jdk"

  cd libbluray
  git config submodule.contrib/libudfread.url "${srcdir}/libudfread"
  git submodule update --init

  ./bootstrap
}

build() {
  cd build
  ../libbluray/configure \
    --prefix=/usr \
    --disable-static \
    --with-java9

  make
}

package() {
  make -C build DESTDIR="${pkgdir}" install
}