blob: 19c8cc3e895756aa5a4fa642ca116b8124663112 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Kevin Brodsky <corax26 at gmail dot com>
# Contributor: Anton Jongsma <anton@felrood.nl>
pkgname=libbobcat
pkgver=5.00.02
pkgrel=1
pkgdesc="Bobcat (Brokken's Own Base Classes And Templates) library"
arch=('i686' 'x86_64')
url="https://fbb-git.gitlab.io/bobcat/"
license=('GPL')
# Versions taken from the 'required' file in sources
depends=('openssl' 'libx11>=1.6.2')
makedepends=('icmake>=8.01.00' 'openssl' 'readline' 'libmilter>=8.14.4'
'libx11>=1.6.2' 'yodl>=3.07.01')
optdepends=()
source=("https://gitlab.com/fbb-git/bobcat/-/archive/${pkgver}/bobcat-${pkgver}.tar.gz")
md5sums=('33a0fd25e274deae7a3e25133ce601f6')
build() {
cd "$srcdir/bobcat-${pkgver}/bobcat"
# Since makepkg always defines CXXFLAGS, it overrides the default value
# defined in the build system, which is problematic because it needs a
# specific C++ version. Add it back here.
CXXFLAGS="$CXXFLAGS -std=c++17"
# Add the -P option not to use precompiled headers, which can be useful since
# they require a lot of free space, compared to a normal compilation:
# ./build -P libraries all
./build libraries all
./build man
}
package() {
cd "$srcdir/bobcat-${pkgver}/bobcat"
# Since 4.01.02, first argument to install is <what to install> (x = all),
# and second is the base directory (absolute path, unlike 4.01.00)
./build install x "$pkgdir"
}
|