summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1e5a1caba981c67498647b266866803096fd2edf (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libbsd-git
pkgver=0.9.1.r18.g7cfa2d4
pkgrel=1
pkgdesc="Provides useful functions commonly found on BSD systems"
arch=('i686' 'x86_64')
url="https://libbsd.freedesktop.org/wiki/"
license=('BSD')
depends=('glibc')
makedepends=('git')
provides=('libbsd')
conflicts=('libbsd')
options=('staticlibs')
source=("git+https://gitlab.freedesktop.org/libbsd/libbsd")
sha256sums=('SKIP')


pkgver() {
  cd "libbsd"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "libbsd"

  ./autogen
  ./configure \
    --prefix="/usr"
  make
}

check() {
  cd "libbsd"

  make check
}

package() {
  cd "libbsd"

  make DESTDIR="$pkgdir" install
  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/libbsd"
}