PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Maintainer: Huang-Huang Bao <eh5@sokka.cn>

_pkgbase=libcamera
pkgbase=libcamera-minimal-git
pkgname=(libcamera-minimal-git)
pkgver=0.0.2.r44.gac42f927
pkgrel=2
pkgdesc="An open source camera stack and framework for Linux, Android, and ChromeOS"
url="https://libcamera.org"
license=(LGPL2.1)
arch=(x86_64)
makedepends=(
  git meson
  openssl
  libelf
  systemd
  libyaml
  gnutls
  python-jinja
  python-ply
  python-yaml
)
source=("git+https://git.libcamera.org/libcamera/${_pkgbase}.git")
sha256sums=('SKIP')

pkgver() {
  cd $_pkgbase
  git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  # make AUR helper happy
  rm -rf builddir || true

  local meson_options=(
    -Dcam=disabled
    -Ddocumentation=disabled
    -Dgstreamer=disabled
    -Dlc-compliance=disabled
    -Dqcam=disabled
    -Dtest=false
    -Dtracing=disabled
    -Dpycamera=disabled
  )

  arch-meson $_pkgbase builddir "${meson_options[@]}"
  meson compile -C builddir
}

# check() {
#   meson test -C builddir --print-errorlogs
# }

package_libcamera-minimal-git() {
  depends=(
    gnutls
    libelf
    libyaml
    libudev.so
  )
  provides=(libcamera libcamera.so libcamera-base.so)
  conflicts=(libcamera)

  meson install -C builddir --destdir "$pkgdir"
}