blob: cbaea63c3fecac43ac290bafbc0a16d706ec3daf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=libcdio-git
pkgver=2.1.0.r60.g5f797b27
pkgrel=1
pkgdesc="Library for CD-ROM and CD image access"
arch=('i686' 'x86_64')
url="https://www.gnu.org/software/libcdio/"
license=('GPL3')
depends=('glibc' 'libcddb')
makedepends=('git' 'help2man')
provides=("libcdio=$pkgver")
conflicts=('libcdio')
options=('staticlibs')
source=("git+https://git.savannah.gnu.org/git/libcdio.git")
sha256sums=('SKIP')
pkgver() {
cd "libcdio"
git describe --long --tags | sed 's/^release-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "libcdio"
autoreconf -fi
./configure \
--prefix="/usr" \
--enable-maintainer-mode \
--disable-example-progs
make
}
check() {
cd "libcdio"
make check
}
package() {
cd "libcdio"
make DESTDIR="$pkgdir" install
sed -i "/LIBCDIO_SOURCE_PATH/s|.*|/* #undef LIBCDIO_SOURCE_PATH */|" \
"$pkgdir/usr/include/cdio/cdio_config.h"
}
|