blob: 0c042d38fc731d5830ab5aef193b6e9471fb9d36 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Alexandre Bouvier <contact@amb.tf>
_pkgname=libchdr
pkgname=$_pkgname-git
pkgver=r140.1d43110
pkgrel=2
pkgdesc="Standalone library for reading MAME's CHDv1-v5 formats"
arch=('aarch64' 'arm' 'armv6h' 'armv7h' 'i686' 'x86_64')
url="https://github.com/rtissera/$_pkgname"
license=('BSD')
depends=('zlib')
makedepends=('cmake' 'git' 'ninja')
provides=("$_pkgname=$pkgver" "$_pkgname.so")
conflicts=("$_pkgname")
source=("git+$url.git")
b2sums=('SKIP')
pkgver() {
cd $_pkgname
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
# prefer user makepkg.conf
sed -i '/CMAKE_C_FLAGS/d;/CMAKE_INTERPROCEDURAL_OPTIMIZATION/d' $_pkgname/CMakeLists.txt
}
build() {
cmake -S $_pkgname -B build -G Ninja \
-DCMAKE_INSTALL_PREFIX=/usr \
-DWITH_SYSTEM_ZLIB=ON \
-Wno-dev
cmake --build build
}
package() {
# shellcheck disable=SC2154
DESTDIR="$pkgdir" cmake --install build
install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname $_pkgname/LICENSE.txt
}
|