blob: 20ec1ac0e55074f907e9e5cc644ffdaa0dc335a6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: acxz <akashpatel2008 at yahoo dot com>
# Contributor: Benjamin Chretien <chretien at lirmm dot fr>
# Contributor: Gonçalo Camelo Neves Pereira <goncalo_pereira@outlook.pt>
# Contributor: midgard <arch dot midgard "at symbol" janmaes "youknowwhat" com>
# Contributor: Zhirui Dai <daizhirui at hotmail dot com>
pkgname=libdart
pkgver=6.13.1
pkgrel=1
pkgdesc="Dynamic Animation and Robotics Toolkit"
arch=('i686' 'x86_64')
url="https://dartsim.github.io"
license=('BSD')
depends=('assimp' 'boost' 'eigen' 'fcl' 'libccd' 'bullet' 'coin-or-ipopt'
'nlopt' 'octomap' 'ode' 'openscenegraph' 'tinyxml2' 'urdfdom'
'glu' 'freeglut' 'libxi' 'libxmu' 'pagmo' 'fmt')
optdepends=('pagmo: pagmo optimizer support')
makedepends=('cmake')
provides=('dartsim')
_pkgname=dart
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/dartsim/${_pkgname}/archive/v${pkgver}.tar.gz"
"gnu13.patch"
)
sha256sums=(
'd3792b61bc2a7ae6682b6d87e09b5d45e325cb08c55038a01e58288ddc3d58d8'
'1a617e94035d4e1259e795908cd76df64f5e64e35a6a8fea250fd264282ead01'
)
# Make libdart use pagmo 2.18.0 instead of 2.17.0
prepare(){
sed -i '9s/7/8/' ${srcdir}/${_pkgname}-${pkgver}/cmake/DARTFindpagmo.cmake
cd ${srcdir}/${_pkgname}-${pkgver}
patch -p1 -i "${srcdir}/gnu13.patch"
}
build() {
mkdir -p "${srcdir}/${_pkgname}-${pkgver}/build"
cd "${srcdir}/${_pkgname}-${pkgver}/build"
export CXXFLAGS="$CFLAGS"
cmake .. \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_INSTALL_LIBDIR="lib" \
-DDART_TREAT_WARNINGS_AS_ERRORS="off"
make
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}/build"
make DESTDIR="${pkgdir}/" install
}
|