PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: Adrián Pérez de Castro <aperez@igalia.com>
pkgname='libdazzle-git'
pkgdesc='Companion library to GObject and GTK+'
license=('GPL3')
pkgver=3.29.1.r9.g221604b
pkgrel=1
provides=('libdazzle')
conflicts=('libdazzle')
makedepends=('meson' 'gobject-introspection' 'vala')
depends=('gtk3')
arch=('x86_64' 'i686')
url='https://gitlab.gnome.org/GNOME/libdazzle'
source=("${pkgname}::git+${url}")
sha512sums=('SKIP')


pkgver () {
	cd "${pkgname}"
	(
		set -o pipefail
		git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	)
}

build () {
	cd "${pkgname}"
	rm -rf build
	meson --buildtype release  \
		--prefix /usr \
		--sysconfdir /etc \
		--localstatedir /var \
		-Denable_gtk_doc=true \
		-Dwith_introspection=true \
		-Dwith_vapi=true \
		build
	ninja -C build
}

package () {
	DESTDIR="${pkgdir}" ninja -C "${pkgname}/build" install
}