blob: f8e1270f269d51f9b4b396f4f1fd1e72c2eabaa7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=libdca-git
pkgver=0.0.7.r2.g95c4bd8
pkgrel=1
pkgdesc="A library for decoding DTS Coherent Acoustics streams"
arch=('i686' 'x86_64')
url="https://www.videolan.org/developers/libdca.html"
license=('GPL2')
depends=('glibc')
makedepends=('git')
provides=("libdca=$pkgver")
conflicts=('libdca')
options=('staticlibs')
source=("git+https://code.videolan.org/videolan/libdca.git")
sha256sums=('SKIP')
pkgver() {
cd "libdca"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "libdca"
./bootstrap
./configure \
--prefix="/usr"
make
}
check() {
cd "libdca"
make check
}
package() {
cd "libdca"
make DESTDIR="$pkgdir" install
}
|