blob: 53e43ab4869fea9775198f75ae4d0df22db34e5a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Eric Biggers <ebiggers3@gmail.com>
pkgname=libdeflate-git
pkgver=1.0.r4.g2b6689d
pkgrel=1
pkgdesc="Heavily optimized library for DEFLATE/zlib/gzip compression and decompression"
arch=('i686' 'x86_64')
url="https://github.com/ebiggers/libdeflate"
license=('MIT')
depends=('glibc')
makedepends=('git')
options=('staticlibs')
source=('git+https://github.com/ebiggers/libdeflate.git')
sha256sums=('SKIP')
conflicts=('libdeflate')
provides=('libdeflate')
pkgver() {
cd libdeflate
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd libdeflate
make
}
check() {
cd libdeflate
make test_programs
./test_checksums
}
package() {
cd libdeflate
make install DESTDIR="$pkgdir"
install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" README* NEWS
install -Dm644 "COPYING" "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
|