PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer:  Eric Biggers <ebiggers3@gmail.com>

pkgname=libdeflate-git
pkgver=0.8.r0.g3d96a83
pkgrel=1
pkgdesc='Heavily optimized library for DEFLATE/zlib/gzip compression and decompression'
arch=('i686' 'x86_64')
url='https://github.com/ebiggers/libdeflate'
license=('MIT')
depends=('glibc')
source=('git+https://github.com/ebiggers/libdeflate.git')
sha256sums=('SKIP')
conflicts=('libdeflate')
provides=('libdeflate')
replaces=('libdeflate')

pkgver() {
	cd libdeflate
	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cd libdeflate
	make
}

package() {
	cd libdeflate

	install -Dm755 gzip "$pkgdir/usr/bin/libdeflate-gzip"
	ln "$pkgdir/usr/bin/libdeflate-gzip" "$pkgdir/usr/bin/libdeflate-gunzip"

	install -Dm755 libdeflate.so "$pkgdir/usr/lib/libdeflate.so"
	install -Dm644 libdeflate.h "$pkgdir/usr/include/libdeflate.h"
	install -Dm644 libdeflate.a "$pkgdir/usr/lib/libdeflate.a"

	install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" README* NEWS
	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" COPYING
}