blob: 874d7df2265a8d9824980f2d540961af6529f4c1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: quietvoid <tcChlisop0@gmail.com>
_pkgname=libdovi
pkgname=${_pkgname}-git
pkgver=3.3.2.r14.g25c397e
pkgrel=1
pkgdesc='Library to read and write Dolby Vision metadata (C-API) - git version'
arch=('x86_64')
url='https://github.com/quietvoid/dovi_tool/tree/main/dolby_vision'
license=('MIT')
depends=('gcc-libs' 'glibc')
makedepends=('git' 'cargo' 'cargo-c')
conflicts=('libdovi')
provides=('libdovi' 'libdovi.so')
source=(git+https://github.com/quietvoid/dovi_tool.git)
sha256sums=(SKIP)
_libdovidir="dovi_tool/dolby_vision"
pkgver() {
cd dovi_tool
git describe --match "libdovi-[0-9]*" --long HEAD --tags | sed 's/^libdovi-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
export RUSTUP_TOOLCHAIN=stable
cd "${_libdovidir}"
cargo fetch --locked --target host-tuple
}
build() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd "${_libdovidir}"
cargo cbuild \
--frozen \
--profile release-deploy \
--prefix=/usr
}
check() {
export RUSTUP_TOOLCHAIN=stable
cd "${_libdovidir}"
cargo test --frozen --all-features
}
package() {
export CARGO_TARGET_DIR=target
cd "${_libdovidir}"
cargo cinstall \
--frozen \
--profile release-deploy \
--prefix /usr \
--destdir "${pkgdir}"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}
|