blob: 2403ab38890f2f782b53c2b1f7228b4609c552da (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer : Lone_Wolf <lone_wolf@klaas-de-kat.nl>
# Contributor : Eric Engestrom <eric@engestrom.ch>
# Contributor : Jan de Groot <jgc@archlinux.org>
pkgname=libdrm-git
_realname=libdrm
pkgver=2.4.114.r2.ge699b28b
pkgrel=1
pkgdesc="Userspace interface to kernel DRM services, master git version"
arch=(i686 x86_64)
license=('custom')
depends=('libpciaccess')
makedepends=('python-docutils' 'meson' 'git' 'ninja')
checkdepends=('cairo' 'cunit')
url="http://dri.freedesktop.org/"
provides=('libdrm')
conflicts=('libdrm')
source=('libdrm::git+https://gitlab.freedesktop.org/mesa/drm.git'
COPYING)
sha512sums=('SKIP'
'b0ca349b882a4326b19f81f22804fabdb6fb7aef31cdc7b16b0a7ae191bfbb50c7daddb2fc4e6c33f1136af06d060a273de36f6f3412ea326f16fa4309fda660')
pkgver() {
cd $_realname
git describe --long --tags --abbrev=8 | sed 's/^libdrm-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
if [ -d _build ]; then
rm -rf _build
fi
}
build() {
meson setup libdrm _build \
--prefix /usr \
--buildtype plain \
--wrap-mode nofallback \
-D udev=false \
-D valgrind=disabled
meson configure --no-pager _build
ninja -C _build
}
check() {
# '-t 10' is needed for the 'threaded' test, which uses the default meson
# test timeout of 30 seconds. This is too short for many systems. It can be
# removed if upstream fixes the issue.
meson test -C _build -t 10
}
package() {
DESTDIR="$pkgdir" ninja -C _build install
install -Dt "$pkgdir"/usr/share/licenses/"$pkgname" -m644 COPYING
}
|