PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgbase=libdvdnav-git
pkgname=(
  'libdvdnav-git'
  'lib32-libdvdnav-git'
)
pkgver=7.0.0.1.gcf11277
pkgrel=1
pkgdesc="Library to navigate DVD disks. (GIT version)"
arch=('x86_64')
license=('GPL2')
url='https://dvdnav.mplayerhq.hu'
makedepends=(
  'git'
  'libdvdread'
  'lib32-libdvdread'
  'glibc'
  'lib32-glibc'
  'meson'
)
provides=('libdvdnav.so')
source=('git+https://code.videolan.org/videolan/libdvdnav.git')
sha256sums=('SKIP')

pkgver() {
  cd libdvdnav
  echo "$(git describe --long --tags | tr - .)"
}

build() {
  cd libdvdnav

  arch-meson . build

  meson compile -C build

  arch-meson . build32 \
    --cross-file lib32

  meson compile -C build32
}

package_libdvdnav-git() {
  depends=(
    'libdvdread.so'
    'glibc'
  )
  provides+=('libdvdnav')
  conflicts=('libdvdnav')

  meson install -C libdvdnav/build --destdir "${pkgdir}"
}

package_lib32-libdvdnav-git() {
  pkgdesc+=" (32-bits)"
  depends=(
    'libdvdread.so'
    'lib32-glibc'
  )
  provides+=('lib32-libdvdnav')
  conflicts=('lib32-libdvdnav')

  meson install -C libdvdnav/build32 --destdir "${pkgdir}"

  rm -fr "${pkgdir}/usr/include"
  rm -fr "${pkgdir}/usr/share"
}