blob: b256c80c755399bd630fb2bdafc6a994be0c225f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
_Name="libE57Format"
pkgname="${_Name,,}"
pkgver=3.3.0
pkgrel=2
pkgdesc="Library for reading & writing the E57 file format"
arch=(
'x86_64'
)
url="https://github.com/asmaloney/${_Name}"
license=(
'BSL-1.0'
)
depends=(
'glibc'
'xerces-c>=3.2'
'libgcc'
'libstdc++'
)
makedepends=(
'cmake>=3.15'
)
provides=(
"${_Name}.so"
)
_pkgsrc="${url##*/}-${pkgver}"
source=(
"${url}/archive/refs/tags/v${pkgver}/${_pkgsrc}.tar.gz"
)
b2sums=('7278504ccc57135975d6b363140d36e3236f1e8e28801407a1085241e960a82c5526668a10543db4733d64a2c60578cbae8dd839bd58bdf0473a213a6f39342b')
build() {
local cmake_options=(
-G 'Unix Makefiles'
-B "${_pkgsrc}/build"
-S "${_pkgsrc}"
-W no-dev
-D CMAKE_BUILD_TYPE:STRING='None'
-D CMAKE_INSTALL_PREFIX:PATH='/usr'
-D BUILD_SHARED_LIBS:BOOL=ON
-D E57_BUILD_TEST:BOOL=OFF
)
cd "${srcdir}"
cmake "${cmake_options[@]}"
cmake --build "${_pkgsrc}/build"
}
# check() {
# local excluded_tests=""
# local ctest_flags=(
# --test-dir "${_pkgsrc}/build"
# --output-on-failure
# --parallel "$(nproc)"
# --exclude-regex "$excluded_tests"
# )
#
# cd "${srcdir}"
# ctest "${ctest_flags[@]}"
# }
package() {
cd "${srcdir}"
DESTDIR="${pkgdir}" cmake --install "${_pkgsrc}/build"
cd "${_pkgsrc}"
install -vDm644 "CHANGELOG.md" "${pkgdir}/usr/share/doc/${pkgname}/CHANGELOG.md"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE.md" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
}
|