PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: J. Emiliano Deustua <edeustua@gmail.com>

pkgname=libecpint-git
_pkgname=libecpint
pkgver=v1.0.6a.r0.g59967ac
pkgrel=1
pkgdesc="A C++ library for the efficient evaluation of integrals over effective core potentials."
arch=('x86_64')
url="https://github.com/robashaw/libecpint"
license=('MIT')
makedepends=('git' 'gcc' 'doxygen' 'cmake' 'python-sphinx' 'gtest')
depends=('pugixml')
provides=('libecpint')
source=("$_pkgname::git+${url}.git")
sha256sums=('SKIP')

pkgver() {
    cd "$_pkgname"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cmake \
        -S "${_pkgname}" \
        -B "${_pkgname}/build" \
        -DCMAKE_CXX_FLAGS='-O3' \
        -DCMAKE_BUILD_TYPE='Release' \
        -DCMAKE_INSTALL_PREFIX='/usr' \
        -DLIBECPINT_MAX_L=7
    make -C "${_pkgname}/build"
}

check() {
    make -C "${_pkgname}/build" test
}

package() {
  cd "${_pkgname}"
  make -C build DESTDIR="$pkgdir" install
}