PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Contributor: Christian Hesse <mail@eworm.de>

pkgname=libetpan-git
pkgver=1.9.4.r86.g5c9eb6b
pkgrel=1
pkgdesc='A portable middleware for email access - git checkout'
arch=('x86_64')
url='https://www.etpan.org/libetpan.html'
license=('BSD-3-Clause AND BSD-3-Clause-Attribution AND BSD-4-Clause')
depends=('gnutls' 'libsasl' 'zlib' 'glibc')
makedepends=('git')
provides=('libetpan')
conflicts=('libetpan')
source=('git+https://github.com/dinhviethoa/libetpan.git')
sha256sums=('SKIP')

pkgver() {
	cd libetpan/
	git describe --long --tags | sed 's/-/.r/;s/-/./g'
}

prepare() {
	cd libetpan/
	NOCONFIGURE=1 ./autogen.sh
}

build() {
	cd libetpan/

	./configure --prefix=/usr \
		--disable-static \
		--disable-db \
		--with-openssl=no \
		--with-gnutls=yes \
		--with-poll
	sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
	make
}

check() {
	cd libetpan/
	make check
}

package() {
	cd libetpan/
	make DESTDIR="${pkgdir}" install
	install -Dm644 COPYRIGHT "${pkgdir}"/usr/share/licenses/${pkgname}/license.txt
}