PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Jiachen Yang <farseerfc@gmail.com>
# AUR Maintainer: Håvard Pettersson <mail@haavard.me>
# Contributor: Ivan Shapovalov <intelfx100 at gmail dot com>

_pkgname=libfilteraudio
pkgname=libfilteraudio-git
pkgver=0.0.1.r0.gada2f4f
pkgrel=1
pkgdesc="An easy to use audio filtering library made from webrtc code"
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h')
url="https://github.com/irungentoo/filter_audio"
license=('BSD')
makedepends=('git')
depends=('glibc')
provides=("${_pkgname}" 'filter_audio')
conflicts=("${_pkgname}" 'filter_audio')
source=(
    "${_pkgname}::git+https://github.com/irungentoo/libfilteraudio.git"
    'LICENSE'
)
sha512sums=('SKIP'
            'ab7ea75c03fab3dfc5d452f04a38b42783f646c2e0acaf8494628bfdf6f83e4b04d470e019385de3e89dd57eb8ef6d02daa6256d4ff311cc66f3999b694ef143')

pkgver() {
    cd ${_pkgname}
    ( set -o pipefail
      git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
          printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    )
}

build() {
    cd ${_pkgname}
    make
}

package() {
    cd ${_pkgname}
    make DESTDIR="$pkgdir" PREFIX="/usr" install
    install -Dm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}