blob: 61a3f2d9ab7d41cfc816d9c31981bb1b29ce6db4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Timothy Gu <timothygu99@gmail.com>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: Thomas Baechler <thomas@archlinux.org>
# Contributor: Ivan Shapovalov <intelfx@intelfx.name>
pkgname=libfprint-git
_pkgname=libfprint
epoch=1
pkgver=1.90.6.r3.g3560a0f
pkgrel=1
pkgdesc="Library for fingerprint readers"
url="https://fprint.freedesktop.org/"
arch=(x86_64)
license=(LGPL)
depends=(libgusb pixman nss systemd-libs)
makedepends=(git meson gtk-doc gobject-introspection systemd)
checkdepends=(python python-cairo python-gobject 'umockdev>=0.13.2')
provides=("libfprint=$pkgver" libfprint-2.so)
conflicts=(libfprint)
groups=(fprint)
source=("git+https://gitlab.freedesktop.org/libfprint/libfprint.git")
sha256sums=('SKIP')
pkgver() {
cd $_pkgname
git describe --tags | sed 's/^V_\|^v//;s/_/./g;s/-/.r/;s/-/./'
}
prepare() {
cd $_pkgname
}
build() {
arch-meson $_pkgname build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
DESTDIR="$pkgdir" meson install -C build
}
|