PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: Pellegrino Prevete (tallero) <pellegrinoprevete@gmail.com>

_pkgname=libgedit-gtksourceview
pkgname="${_pkgname}-git"
pkgver=299.0.3+5+gffb59486
pkgrel=1
_pkgdesc=("Library that extends GtkTextView, the standard GTK "
          "widget for multiline text editing.")
pkgdesc="${_pkgdesc[@]}"
arch=(x86_64)
url="https://github.com/gedit-technology/${_pkgname}"
license=(LGPL2.1)
depends=(
  'gtk3'
  'libxml2'
)
makedepends=(
  'git'
  'gobject-introspection'
  'meson'
)
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
source=("git+${url}")
sha256sums=('SKIP')

pkgver() {
  cd "${_pkgname}"
  git describe --tags | sed 's/-/+/g'
}

build() {
  arch-meson "${_pkgname}" build
  meson compile -C build
}

check() {
  xvfb-run -s '-screen 0 1920x1080x24 -nolisten local' \
    meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "${pkgdir}"
}