blob: f5cbcb8a8e6c6d57012a5c287f9963e8a54d7723 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Jeremy "Ichimonji10" Audet <ichimonji10 at gmail dot com>
# Contributor: Jonjo McKay <jonjo@jonjomckay.com>
pkgname=libgroove
pkgver=4.3.0
pkgrel=1
pkgdesc='Library that provides decoding and encoding of audio on a playlist.'
arch=(i686 x86_64)
url='https://github.com/andrewrk/libgroove'
license=(MIT)
depends=(sdl2 chromaprint libebur128)
makedepends=(cmake yasm)
conflicts=(libgroove-git)
options=('strip' ccache)
source=("https://github.com/andrewrk/libgroove/archive/${pkgver}.tar.gz")
sha256sums=('76f68896f078a9613d420339ef887ca8293884ad2cd0fbc031d89a6af2993636')
prepare() {
mkdir "${srcdir}/${pkgname}-${pkgver}/build"
cp "${srcdir}/${pkgname}-${pkgver}/example/libgroove.pc" "${srcdir}/"
for pattern in \
's|^libdir=$|libdir=/usr/lib|' \
's|^includedir=$|includedir=/usr/include/groove|' \
"s|^Version:$|Version: ${pkgver}|"
do sed -i "${pattern}" "${srcdir}/libgroove.pc"
done
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}/build"
cmake ../ -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
make -C "${srcdir}/${pkgname}-${pkgver}/build" DESTDIR="${pkgdir}/" install
install -Dm 644 "${srcdir}/${pkgname}-${pkgver}/LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
# Created in the `prepare` function.
install -Dm 644 "${srcdir}/libgroove.pc" \
"${pkgdir}/usr/lib/pkgconfig/libgroove.pc"
}
# vim:set ts=2 sw=2 et:
|