PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer:
# Contributor: Ignacy Kuchciński (ignapk) <ignacykuchcinski@gmail.com>

_pkgname="libgweather"
pkgname="$_pkgname-git"
pkgver=4.4.0.r8.g57a116bf
pkgrel=1
pkgdesc='Location and timezone database and weather-lookup library'
url='https://gitlab.gnome.org/GNOME/libgweather'
arch=(x86_64)
license=(LGPL)

depends=(
  'dconf'
  'geocode-glib-2'
  'json-glib'
  'libsoup3'
  'libxml2'
)
makedepends=(
  'gi-docgen'
  'git'
  'gobject-introspection'
  'meson'
  'python-gobject'
  'vala'
)

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  arch-meson "$_pkgsrc" build -D gtk_doc=true
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs || true
}

package() {
  provides+=(
    "libgweather-4=${pkgver%%.r*}"
    "libgweather-4.so"
  )
  conflicts=(
    'libgweather-4'
  )

  meson install -C build --destdir "${pkgdir:?}"
}