summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1cd13e50551ac86575c8cd970ed88e9ecb6d04eb (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libidn2-git
pkgver=2.3.0.r26.g985686b
pkgrel=1
pkgdesc="An implementation of IDNA 2008 and TR46"
arch=('i686' 'x86_64')
url="https://www.gnu.org/software/libidn/#libidn2"
license=('GPL' 'LGPL')
depends=('glibc' 'libunistring')
makedepends=('git' 'gengetopt' 'rsync' 'wget' 'gtk-doc' 'ruby-ronn')
provides=('libidn2' 'libidn2.so')
conflicts=('libidn2')
options=('staticlibs')
source=("git+https://gitlab.com/libidn/libidn2.git")
sha256sums=('SKIP')


pkgver() {
  cd "libidn2"

  git describe --long --tags | sed 's/^libidn2.//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "libidn2"

  ./bootstrap
  ./configure \
    --prefix="/usr" \
    --enable-gtk-doc
  make
}

check() {
  cd "libidn2"

  make check
}

package() {
  cd "libidn2"

  make DESTDIR="$pkgdir" install
}