PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: Evgeniy Dombek <edombek@yandex.ru>

pkgname=libindi-git
pkgver=v2.0.4.20.gb24472523
pkgrel=1
pkgdesc='A distributed control protocol designed to operate astronomical instrumentation'
url='https://www.indilib.org/index.php?title=Main_Page'
license=(GPL2)
arch=(x86_64 aarch64)
depends=(libnova cfitsio libjpeg gsl libtheora fftw libev rtl-sdr)
makedepends=(cmake qt5-base)
provides=('libindi')
conflicts=('libindi')
source=('git+https://github.com/indilib/indi')
sha512sums=('SKIP')
options=("staticlibs")

pkgver() {
  cd "indi"
  git describe --long --tags | sed 's/-/./;s/-/./'
}

build() {
  cmake -B build -S indi \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DINDI_BUILD_QT5_CLIENT=ON \
    -DUDEVRULES_INSTALL_DIR=/usr/lib/udev/rules.d \
    -DCMAKE_C_FLAGS="$CFLAGS -ffat-lto-objects" \
    -DCMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects -Wp,-U_GLIBCXX_ASSERTIONS"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}