blob: 50c805aa2f23e4ad2d6fe8b653ff88db1b2e9103 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Sebastian Baberowski <sebastian@baberowski.com>
pkgname=libindi-gpsd
pkgver=1.8.5
pkgrel=2
pkgdesc="3rd party drivers for INDI: GPSD"
url="http://www.indilib.org/index.php?title=Main_Page"
license=(GPL2)
arch=(i686 x86_64)
depends=(libindi=${pkgver})
makedepends=(cmake)
source=("https://github.com/indilib/indi-3rdparty/archive/v${pkgver}.tar.gz" "gpsd-api-v10-fix.diff")
sha256sums=("acbddca69c25b2c46ebc0982e8dbbf4912a43f6a4b45d46b007deab8805caed8" "9fbaf514fa4389ab494978d5e2f12783b63179ae4eda88e4865a772cd90a42ec")
prepare() {
mkdir -p build
cd indi-3rdparty-${pkgver}
#set all to off by default
sed -i -e '/option(WITH_.*On/s/ On/ Off/' CMakeLists.txt
patch -Np1 < ${srcdir}/gpsd-api-v10-fix.diff
}
build() {
cd build
cmake -DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DWITH_GPSD=On \
../indi-3rdparty-${pkgver}
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|