blob: 63e45d4a873c4028548a821a52c66e5467a9b799 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: bilabila <bilabila@qq.com>
_pkgname=libinput
_patch=multiplier.patch
pkgname=$_pkgname-multiplier
pkgver=1.24.0
pkgrel=1
pkgdesc='libinput with scroll multiplier patch'
arch=(x86_64)
url=http://freedesktop.org/wiki/Software/libinput
provides=($_pkgname=$pkgver)
conflicts=($_pkgname)
license=(custom)
depends=(mtdev systemd libevdev libwacom systemd-libs glibc)
makedepends=(gtk4 meson wayland-protocols check)
checkdepends=('python-pytest')
optdepends=('gtk4: libinput debug-gui'
'python-pyudev: libinput measure'
'python-libevdev: libinput measure')
source=(https://gitlab.freedesktop.org/libinput/libinput/-/archive/$pkgver/$_pkgname-$pkgver.tar.bz2
$_patch)
sha512sums=(924554d62d232f99851db51386653e67083b8f3b8203b5d848294c08880e1ba153f80699900210d1b5b31566a2ef6bd4aa0662f107a2dcaed1fe0f7e1fb784db
c6a2793e592c69829e542c91aafc2de42c0eddec1f2570a465590584164a64d3828507f2f1194ec48f0f5d85aa624054c101287e981b2a82a3a43d85b426aa94)
prepare() {
cd "${srcdir}"/$_pkgname-$pkgver
patch -Np1 -i ../$_patch
}
build() {
arch-meson $_pkgname-$pkgver build \
-D udev-dir=/usr/lib/udev \
-D documentation=false
# Print config
# meson configure build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
install -Dvm644 $_pkgname-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$_pkgname/LICENSE
}
|