blob: c59298eb341f8546747392babb6e103d98d05128 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id$
# Maintainer: R. Agnese <ragnese at tutanota.de>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Jan de Groot
# Contributor: Reddit user "oniram" (https://www.reddit.com/r/linux/comments/4tr0ji/libinput_is_done/d5jx8g2)
_basename=libinput
pkgname=libinput-swap-two-and-three-finger-tap
pkgver=1.4.0
pkgrel=1
pkgdesc="Input device management and event handling library with patch to swap two and three finger tap on touchpads"
arch=(i686 x86_64)
url="http://www.freedesktop.org/wiki/Software/libinput/"
license=(custom:X11)
depends=('mtdev' 'systemd' 'libevdev' 'libwacom')
conflicts=('libinput')
provides=("${_basename}=$pkgver")
# currently no doc files to install
#makedepends=('doxygen' 'graphviz' 'gtk3')
#checkdepends=('check' 'libunwind')
source=(http://freedesktop.org/software/${_basename}/${_basename}-$pkgver.tar.xz{,.sig}
swap-two-and-three-finger-tap.patch)
sha256sums=('76ef10874519d1a67b57e5c68ede06106b9fbf611a3ecf69c84886107c67b420'
'SKIP'
'be55ea78922c5f36a57cf267f02fe291d9fe18524e533101bda7204c7630e455')
validpgpkeys=('3C2C43D9447D5938EF4551EBE23B7E70B467F0BF') # Peter Hutterer (Who-T) <office@who-t.net>
prepare() {
cd ${_basename}-$pkgver
patch -p1 <../swap-two-and-three-finger-tap.patch
}
build() {
cd ${_basename}-$pkgver
./configure --prefix=/usr --disable-static
make
}
check() {
cd ${_basename}-$pkgver
# disabled for now:
# https://github.com/libcheck/check/issues/18
# make check
}
package() {
cd ${_basename}-$pkgver
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${_basename}/COPYING"
}
|