blob: a2b76c89485e834829193574a34b6b66c9146a03 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=libjcat-git
pkgver=0.1.12.r5.ge81185d
pkgrel=1
pkgdesc="Library for reading and writing Jcat files"
arch=('i686' 'x86_64')
url="https://github.com/hughsie/libjcat"
license=('LGPL')
depends=('glibc' 'gpgme' 'json-glib')
makedepends=('git' 'gobject-introspection' 'help2man' 'meson' 'vala')
provides=("libjcat=$pkgver")
conflicts=('libjcat')
options=('staticlibs')
source=("git+https://github.com/hughsie/libjcat.git")
sha256sums=('SKIP')
pkgver() {
cd "libjcat"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "libjcat"
meson setup \
--buildtype=plain \
--prefix="/usr" \
--sbindir="bin" \
--libexecdir="/usr/lib" \
-Ddefault_library="both" \
"_build"
meson compile -C "_build"
}
check() {
cd "libjcat"
meson test -C "_build"
}
package() {
cd "libjcat"
meson install -C "_build" --destdir "$pkgdir"
}
|