blob: e08cb3f5fc6809cfad89144cdf1bfd17d9c8e395 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Muflone http://www.muflone.com/contacts/english/
# Contributor: benklett <b.klettbach@gmail.com>
pkgname=libjpeg9
pkgver=9e
pkgrel=1
pkgdesc="JPEG image compression"
arch=('x86_64')
url="http://www.ijg.org/"
license=('custom')
depends=('glibc')
makedepends=('libtool')
source=("http://www.ijg.org/files/jpegsrc.v${pkgver}.tar.gz")
sha256sums=('4077d6a6a75aeb01884f708919d25934c93305e49f7e3f36db9129320e6f4f3d')
build() {
cd "jpeg-${pkgver}"
./configure --prefix=/usr --enable-shared --enable-static
make
}
check() {
cd "jpeg-${pkgver}"
make -k check
}
package() {
cd "jpeg-${pkgver}"
make prefix="${pkgdir}/usr" mandir="${pkgdir}/usr/share/man" install
# Install license file
install -m 755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
install -m 644 README "${pkgdir}/usr/share/licenses/libjpeg9/README"
# Copy header files
install -m 755 -d "${pkgdir}/usr/include/${pkgname}"
install -m 644 jpegint.h "${pkgdir}/usr/include/${pkgname}"
cd "${pkgdir}"
# Remove static libraries
rm "usr/lib/libjpeg.a"
rm "usr/lib/libjpeg.so"
rm "usr/lib/libjpeg.la"
# Rename pkgconfig libraries
mv "usr/lib/pkgconfig/libjpeg.pc" "usr/lib/pkgconfig/${pkgname}.pc"
# Rename binary executables
for _file in usr/bin/*
do
mv ${_file} ${_file}9
done
# Rename man pages
for _file in usr/share/man/man1/*
do
mv ${_file} ${_file%.1}9
done
# Move header files
mv usr/include/*.h "usr/include/${pkgname}"
}
|