summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 60f304209644bda3029b5ad40dc2a00f81a0e3c3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Original Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
#
# Copied from AUR3
#

pkgname=libkdcraw-frameworks-git
pkgver=5.0.0.r1055.9850efb
pkgrel=1
pkgdesc="A C++ interface used to decode RAW picture. KF5 Frameworks branch (GIT version)"
url='https://projects.kde.org/projects/kde/kdegraphics/libs/libkdcraw'
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
depends=('kconfig' 'ki18n' 'libraw' 'hicolor-icon-theme')
makedepends=('extra-cmake-modules' 'kdoctools' 'git' 'python')
conflicts=('libkdcraw')
provides=('libkdcraw')
source=("git://anongit.kde.org/libkdcraw#branch=frameworks")
sha1sums=('SKIP')
install=libkdcraw-frameworks-git.install

pkgver() {
  cd libkdcraw
  _ver="$(cat CMakeLists.txt | grep -e KDCRAW_LIB_MAJOR_VERSION -e KDCRAW_LIB_MINOR_VERSION -e KDCRAW_LIB_PATCH_VERSION | head -n3 | cut -d '"' -f2)"
  echo "$(echo ${_ver} | tr ' ' .).r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../libkdcraw \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  make
}

package() {
  make -C build DESTDIR="${pkgdir}" install
}