PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer : Daniel Bermond < gmail-com: danielbermond >

pkgname=libklvanc-git
_srcname=libklvanc
pkgver=r430.68c5c7d
pkgrel=1
pkgdesc='Library which can be used for parsing/generation of Vertical Ancillary Data (VANC) (git version)'
arch=('i686' 'x86_64')
url='https://github.com/stoth68000/libklvanc/'
license=('LGPL')
depends=('ncurses')
makedepends=('git' 'zlib')
provides=('libklvanc')
conflicts=('libklvanc')
source=('git+https://github.com/stoth68000/libklvanc.git')
sha256sums=('SKIP')

prepare() {
    cd "$_srcname"
    
    ./autogen.sh --build
}

pkgver() {
    cd "$_srcname"
    
    # git, no tags available
    printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "$_srcname"
    
    ./configure \
        --prefix='/usr' \
        --enable-shared='yes' \
        --enable-static='no'
    
    make
}

package() {
    cd "$_srcname"
    
    make DESTDIR="$pkgdir" install
}