PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

# Maintainer: kotontrion <kotontrion@tutanota.de>

pkgbase=libkompass-git
pkgname=(libkompass-git kompass-git)
pkgver=r122.d507477
pkgrel=3
pkgdesc="a gtk4 wayland desktop shell"
arch=(x86_64)
license=(GPL-3.0-only)
url="https://codeberg.org/kotontrion/kompass"
depends=(
  gtk4
  gtk4-layer-shell
  glib2
  libadwaita
  libnm
  libnma-gtk4
  libastal-meta
  libportal
  slurp
  wf-recorder
)
makedepends=(
  meson
  blueprint-compiler
  dart-sass
  git
  gobject-introspection
  vala
)
source=("${pkgname}::git+https://codeberg.org/kotontrion/kompass.git")
sha256sums=('SKIP')

pkgver() {
  cd "$pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
  cd "$pkgname"
  arch-meson build
  meson compile -C build
}

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
    done
}

package_libkompass-git() {

  provides+=(libkompass libkompass.so=0-64)
  pkgdesc="a library providing some useful widgets for building desktop shells"

  cd "$pkgname"
  meson install -C build --destdir "$pkgdir"
  
  cd "$pkgdir"

  _pick kompass usr/bin/kompass
}

package_kompass-git() {
  provides+=(kompass)
  depends+=(libkompass-git)
  mv kompass/* "$pkgdir"
}