blob: 022fc30c42d5aaba2f25436c9be3f955871a9567 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmailcom>
# Contributor: Michael Hansen <zrax0111 gmail com>
# Contributor: Nicolas Quiénot < niQo at aur >
pkgname="libkqueue"
pkgver=2.7.0
pkgrel=1
pkgdesc="Userspace implementation of the kqueue kernel(2) event notification mechanism found in BSD-based systems"
url="https://github.com/mheily/${pkgname}"
arch=(
'i686'
'x86_64'
)
license=(
'ISC AND BSD-2-Clause'
)
depends=(
'glibc'
'libgcc'
)
makedepends=(
'cmake>=3.8.0'
'git'
)
provides=(
"${pkgname}.so"
)
_pkgsrc="${url##*/}"
source=(
"${_pkgsrc}::git+${url}.git#tag=v${pkgver}" # ?signed"
)
sha256sums=('82774311084d28e225014f1913da179258e755c101933b58a83bf0a09ee85891')
validpgpkeys=(
'FD31307742EC7FCD32FE5EE256CF27F930A8CAA2' # Arran Cudbard-Bell <a.cudbardb@freeradius.org>
)
build() {
local cmake_options=(
-B "${_pkgsrc}/build"
-S "${_pkgsrc}"
-G 'Unix Makefiles'
-W no-dev
-D CMAKE_BUILD_TYPE:STRING='None'
-D CMAKE_INSTALL_PREFIX:PATH='/usr'
)
cd "${srcdir}"
cmake "${cmake_options[@]}"
cmake --build "${cmake_options[1]}"
}
package() {
cd "${srcdir}"
DESTDIR="${pkgdir}" cmake --install "${_pkgsrc}/build"
cd "${_pkgsrc}"
install -vDm644 "ChangeLog" "${pkgdir}/usr/share/doc/${pkgname}/CHANGELOG"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|