PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: eisensheng <eisensheng@mailbox.org>
_pkgname=Mimick
pkgname=libmimick-git
pkgver=v0.2.0.r40.g435f41d
pkgrel=1
pkgdesc='KISS Cross-platform C Mocking library.'
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="https://github.com/Snaipe/Mimick"
license=('MIT')
makedepends=('cmake')
provides=('libmimick')
source=('git+https://github.com/Snaipe/Mimick.git')
md5sums=(SKIP)

pkgver() {
  cd "${srcdir}/${_pkgname}"

  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "${srcdir}/${_pkgname}/"

  [[ -d build ]] || mkdir build
}

build() {
  cd "${srcdir}/${_pkgname}/build"

  cmake \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    ..
  make
}

check() {
  cd "${srcdir}/${_pkgname}/build"

  # Tests are failing.
  # make test
}

package() {
  cd "${srcdir}/${_pkgname}/build"

  make DESTDIR="${pkgdir}" LIBDIR="${pkgdir}/usr/lib" install

  install -D -m644 ../LICENSE \
    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}