blob: d542970a82455e6f7c5662e062408c9645d36781 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: xiretza <xiretza+aur@xiretza.xyz>
# Contributor: Yunhui Fu <yhfudev@gmail.com>
_pkgname=libmirisdr
pkgname=$_pkgname-git
epoch=1
pkgver=r5.59ba372
pkgrel=1
pkgdesc="Software for the Mirics MSi2500 + MSi001 SDR platform."
arch=('i686' 'x86_64' 'arm')
url="https://gitea.osmocom.org/sdr/$_pkgname"
license=('GPL2')
depends=(
'libusb'
)
makedepends=(
'git'
'cmake'
)
#optdepends=()
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=("git+$url")
md5sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cmake -B build -S "$_pkgname" \
-DCMAKE_BUILD_TYPE='None' \
-DCMAKE_INSTALL_PREFIX=/usr
make -C build
}
package() {
make -C build DESTDIR="$pkgdir" install
install -Dm644 "$_pkgname/mirisdr.rules" "${pkgdir}/etc/udev/rules.d/99-mirisdr.rules"
}
# vim:set ts=4 et:
|