blob: ce18bc2453e610b840d38cde15aa358ead83d3f0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
pkgname=libmodulemd
pkgver=2.13.0
pkgrel=1
pkgdesc="C Library for manipulating module metadata files"
arch=('i686' 'x86_64')
url="https://github.com/fedora-modularity/$pkgname"
license=('custom:MIT')
depends=('file' 'glib2' 'libyaml' 'rpm-tools')
makedepends=('gobject-introspection' 'gtk-doc' 'help2man' 'meson>=0.47' 'python-gobject')
optdepends=('python-gobject: for python bindings')
source=("$url/releases/download/$pkgver/${pkgname#lib}-$pkgver.tar.xz")
sha256sums=('cc72ce5ff48ce9a4f6c9b6606ccf5a0e75c59c35449668cfe985722ef28f9cbc')
prepare() {
mv "${pkgname#lib}-$pkgver" "$pkgname-$pkgver"
}
build() {
cd "$pkgname-$pkgver"
arch-meson build -Ddeveloper_build=false
ninja -C build
}
check() {
cd "$pkgname-$pkgver"
ninja -C build test
}
package() {
cd "$pkgname-$pkgver"
DESTDIR="$pkgdir/" ninja -C build install
install -Dp -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
install -Dp -m644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
# vim: set ft=sh ts=4 sw=4 noet:
|