blob: d11acb15390b707f50a47330b24e05c9e13bde1a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
pkgname=libmodulemd
pkgver=2.0.0beta2
pkgrel=1
pkgdesc="C Library for manipulating module metadata files"
arch=('i686' 'x86_64')
url="https://github.com/fedora-modularity/$pkgname"
license=('custom:MIT')
depends=('glib2' 'libyaml')
makedepends=('gobject-introspection' 'gtk-doc' 'meson' 'python-gobject')
optdepends=('python-gobject: for python bindings')
source=("$url/releases/download/$pkgname-$pkgver/${pkgname#lib}-$pkgver.tar.xz")
md5sums=('96a6bf20d7615f830d67fc083da560c1')
prepare() {
mv "${pkgname#lib}-${pkgver%beta*}" "$pkgname-$pkgver"
}
build() {
cd "$pkgname-$pkgver"
arch-meson build -Ddeveloper_build=false -Dbuild_api_v1=true
ninja -C build
}
check() {
cd "$pkgname-$pkgver"
ninja -C build test
}
package() {
cd "$pkgname-$pkgver"
DESTDIR="$pkgdir/" ninja -C build install
install -Dp -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
install -Dp -m644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
# vim: set ft=sh ts=4 sw=4 noet:
|