summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 4d232f4ec36e82ff8cbfbc2b1041edbca69495fe (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libnetfilter_log-git
pkgver=1.0.2.r4.gbd26974
pkgrel=1
pkgdesc="Userspace library providing interface to packets that have been logged by the kernel packet filter"
arch=('i686' 'x86_64')
url="https://netfilter.org/projects/libnetfilter_log/index.html"
license=('GPL')
depends=('libnfnetlink' 'libmnl')
makedepends=('git')
provides=("libnetfilter_log=$pkgver")
conflicts=('libnetfilter_log')
source=("git://git.netfilter.org/libnetfilter_log")
sha256sums=('SKIP')


pkgver() {
  cd "libnetfilter_log"

  git describe --long --tags | sed 's/^libnetfilter_log-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "libnetfilter_log"

  ./autogen.sh
  ./configure \
    --prefix="/usr"
  make
}

package() {
  cd "libnetfilter_log"

  make DESTDIR="$pkgdir" install
}