PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Maintainer: Ivy Foster <ivy.foster@gmail.com>

pkgname='libnsutils-git'
pkgver=0.0.2.r0.g59ceb7f
pkgrel=2
pkgdesc='NetSurf Utilities'
url='http://source.netsurf-browser.org/libnsutils.git/'
license=('MIT')

makedepends=('git' 'netsurf-buildsystem-git')
provides=('libnsutils')
conflicts=('libnsutils')

arch=('x86_64' 'i686')
source=('git://git.netsurf-browser.org/libnsutils.git')
sha256sums=('SKIP')

pkgver() {
	cd libnsutils
	git describe --long | sed 's:release/::; s:-\([0-9]\+\)-:.r\1.:'
}

prepare() {
	sed 's:-D_BSD_SOURCE::' -i libnsutils/Makefile
}

build() {
	make -C libnsutils PREFIX=/usr INCLUDEDIR=include \
		LIBDIR=lib COMPONENT_TYPE=lib-shared
}

check() {
	make -C libnsutils PREFIX=/usr INCLUDEDIR=include \
		LIBDIR=lib COMPONENT_TYPE=lib-shared test
}

package() {
	cd libnsutils
	make DESTDIR="$pkgdir" PREFIX=/usr INCLUDEDIR=include \
		LIBDIR=lib COMPONENT_TYPE=lib-shared install
	install -Dm644 COPYING \
		"$pkgdir/usr/share/licenses/netsurf/libnsutils"
}