blob: 7390ac3abb072e7c1592fb2a6977dadceb2be5e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Julie Shapiro <jshapiro at nvidia dot com>
# Contributor: Kien Dang <mail at kien dot ai>
pkgname=('libnvidia-container' 'libnvidia-container-tools')
pkgbase=libnvidia-container
pkgver=1.14.6
pkgrel=1
_nvmodver=550.54.14
_tirpcver=1.3.2
pkgdesc="NVIDIA container runtime library"
arch=('x86_64')
url='https://github.com/NVIDIA/libnvidia-container'
license=('BSD-3-Clause AND Apache-2.0 AND GPL-3.0-or-later AND LGPL-3.0-or-later AND GPL-2.0-only')
depends=('libcap' 'libelf' 'libseccomp' 'libtirpc')
makedepends=('bmake' 'git' 'go' 'lsb-release' 'rpcsvc-proto')
_commit=d2eb0afe86f0b643e33624ee64f065dd60e952d4 # tags/v1.14.6^0
source=("git+https://github.com/NVIDIA/libnvidia-container.git#commit=${_commit}"
"nvidia-modprobe-${_nvmodver}.tar.gz::https://github.com/NVIDIA/nvidia-modprobe/archive/${_nvmodver}.tar.gz"
'fix-makefile.patch'
'no-manual-debuginfo.patch')
noextract=("nvidia-modprobe-${_nvmodver}.tar.gz")
sha256sums=('SKIP'
'5687b0dfa6087dd480ae91e91ff1dca975794e35a2edcf9ec08d8f9cb98ef905'
'ca38bc4d67dc1c585a21d903dfe6dc1ca79db04320e76fff93b82b4d102896fe'
'4c0ffca77dee2d0c98ea92716b5c3cff0d41f974000fea29ca905435d3acbe8e')
pkgver() {
cd "$pkgbase"
git describe --tags | sed 's/^v//;s/-/+/g'
}
prepare(){
cd "$pkgbase"
# NVIDIA modprobe configuration based on & mk/nvidia-modprobe.mk
mkdir -p "deps/src/nvidia-modprobe-${_nvmodver}"
bsdtar -xvf "$srcdir/nvidia-modprobe-${_nvmodver}.tar.gz" -C "deps/src/nvidia-modprobe-${_nvmodver}/" \
--strip-components=1 -xz "nvidia-modprobe-${_nvmodver}/modprobe-utils"
touch "deps/src/nvidia-modprobe-${_nvmodver}/.download_stamp"
patch -d "deps/src/nvidia-modprobe-${_nvmodver}" -p1 < mk/nvidia-modprobe.patch
patch -Np1 -i ../fix-makefile.patch
patch -Np1 -i ../no-manual-debuginfo.patch
}
build(){
cd "$pkgbase"
make prefix=/usr WITH_LIBELF=yes
}
package_libnvidia-container() {
cd "$pkgbase"
make prefix=/usr DESTDIR="$pkgdir" install
# remove empty leftover directory
rm -rf "$pkgdir/usr/lib/debug"
# remove CLI for tools
rm -rf "$pkgdir/usr/bin"
# remove duplicate licenses
rm -rf "$pkgdir/usr/share"
# install BSD-3-Clause license
install -Dm644 NOTICE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
package_libnvidia-container-tools() {
pkgdesc+=" (command-line tools)"
depends=('libnvidia-container')
cd "$pkgbase"
make prefix=/usr DESTDIR="$pkgdir" install
# remove lib and include
rm -rf "$pkgdir"/usr/{include,lib}
# remove duplicate licenses
rm -rf "$pkgdir/usr/share"
# install BSD-3-Clause license
install -Dm644 NOTICE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|