blob: bbb4eeb68b9d06919598963dca5838ba2165d45b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Maintainer: Rafael Dominiquini <rafaeldominiquini at gmail dot com>
# Contributor: Andréas Caumeil <andreas.caumeil@proton.me>
# Contributor: Caleb Maclennan <caleb@alerque.com>
# Contributor: David Runge <dvzrv@archlinux.org>
# Contributor: Martin Wimpress <code@flexion.org>
# Contributor: Foster McLane <fkmclane@gmail.com>
# Contributor: Jonathan Thomas <jonathan@openshot.org>
pkgbase=libopenshot-audio
pkgname=(
libopenshot-audio
libopenshot-audio-docs
)
pkgver=0.6.0
pkgrel=1
pkgdesc="A high-quality audio editing and playback library used by libopenshot."
arch=(x86_64)
url="https://github.com/openshot/libopenshot-audio"
license=(GPL3)
makedepends=(
alsa-lib
cmake
doxygen
freetype2
libx11
python
zlib
)
source=($url/archive/v$pkgver/$pkgname-v$pkgver.tar.gz)
sha512sums=('b6f9e6a206c177778041d7897b86c3512b79038113d906422c491509c45a494edbf50b0ce448cffecdd8173937cf5d8e8f13590c69d372d0991caaa83e71c6aa')
b2sums=('497646faa0227d7872bb611ed308b9fe28d95708ce28adbf717ec4d07efb49214378395527ce13f250e2978d041edacb8fdd23869b58dd4d753e1ebbafad3120')
_pick() {
local p="$1" f d; shift
for f; do
d="$srcdir/$p/${f#$pkgdir/}"
mkdir -p "$(dirname "$d")"
mv "$f" "$d"
rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
done
}
build() {
local cmake_options=(
-B build
-D CMAKE_BUILD_TYPE=None
-D CMAKE_INSTALL_PREFIX=/usr
-S $pkgname-$pkgver
-W no-dev
)
cmake "${cmake_options[@]}"
cmake --build build --verbose
}
check() {
ctest --test-dir build --output-on-failure
}
package_libopenshot-audio() {
depends=(
alsa-lib
gcc-libs
glibc
zlib
)
optdepends=('libopenshot-audio-docs: for documentation')
provides=(libopenshot-audio.so)
DESTDIR="$pkgdir" cmake --install build
(
cd "$pkgdir"
_pick libopenshot-audio-docs usr/share/doc/
)
install -vDm 644 $pkgname-$pkgver/{AUTHORS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
}
package_libopenshot-audio-docs() {
pkgdesc+=" - documentation"
mv -v $pkgname/* "$pkgdir"
}
|