PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Daniel Bermond < gmail-com: danielbermond >

pkgname=libopenshot-git
pkgver=0.2.2.r0.gc90fb9b
pkgrel=1
pkgdesc='A high quality, open-source video editing, animation, and playback library for C++, Python, and Ruby (git version)'
arch=('i686' 'x86_64')
url='http://www.openshot.org/'
license=('LGPL3')
depends=('libmagick6' 'ffmpeg' 'libx264' 'libopenshot-audio' 'python' 'jsoncpp' 'qt5-multimedia' 'zeromq')
makedepends=('git' 'cmake' 'doxygen' 'swig' 'unittestpp')
provides=('libopenshot')
conflicts=('libopenshot')
source=("$pkgname"::'git+https://github.com/OpenShot/libopenshot.git')
sha256sums=('SKIP')

pkgver() {
    cd "$pkgname"
    
    # git, tags available
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

build() {
    cd "$pkgname"
    
    mkdir -p build
    cd build
    
    cmake \
        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
        -DUSE_SYSTEM_JSONCPP:BOOL='ON' \
        -DMAGICKCORE_HDRI_ENABLE='1' \
        -DMAGICKCORE_QUANTUM_DEPTH='16' \
        -DENABLE_RUBY='OFF' \
        -Wno-dev \
        ..
    make
}

package() {
    cd "${pkgname}/build"
    
    make DESTDIR="$pkgdir" install
}