PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: txtsd <aur.archlinux@ihavea.quest>

pkgname=libopensles-standalone-git
_pkgname="${pkgname%-git}"
pkgver=r280.605a83f
pkgrel=1
pkgdesc="A lightly patched version of Google's libOpenSLES implementation"
url='https://gitlab.com/android_translation_layer/libopensles-standalone'
arch=(x86_64 aarch64 armv7h)
license=('Apache-2.0')
depends=(
  glibc
  libsndfile
  sdl2
)
makedepends=(
  git
  jdk8-openjdk
  meson
)
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("git+${url}.git")
sha256sums=('SKIP')

pkgver() {
  cd ${_pkgname}
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  meson subprojects download --sourcedir="${_pkgname}"
}

build() {
  arch-meson "${_pkgname}" build
  meson compile -C build
}

check() {
  meson test --no-rebuild --print-errorlogs -C build
}

package() {
  meson install --no-rebuild -C build --destdir "${pkgdir}"
}