summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 83830c0c2e8024df008b8364a6137b0bde1f0182 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=libopusenc-git
pkgver=0.2.1.r2.g9cb17c6
pkgrel=1
pkgdesc="High-level API for encoding .opus files"
arch=('i686' 'x86_64')
url="https://opus-codec.org/"
license=('BSD')
depends=('glibc' 'opus')
makedepends=('git')
provides=('libopusenc')
conflicts=('libopusenc')
options=('staticlibs')
source=("git+https://gitlab.xiph.org/xiph/libopusenc.git")
sha256sums=('SKIP')


pkgver() {
  cd "libopusenc"

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "libopusenc"

  ./autogen.sh
  ./configure \
    --prefix="/usr"
  make
}

package() {
  cd "libopusenc"

  make DESTDIR="$pkgdir" install

  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/libopusenc"
  rm "$pkgdir/usr/share/doc/libopusenc/COPYING"
}