blob: e9a5eb1dbf8d2e22b29e94736087c4cb9dc3ac50 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Simon Legner <Simon.Legner@gmail.com>
pkgname=libosmium
pkgver=2.15.4
pkgrel=2
pkgdesc="Fast and flexible C++ library for working with OpenStreetMap data."
url="https://osmcode.org/libosmium/"
arch=('any')
license=('custom')
makedepends=('cmake')
depends=('expat' 'zlib' 'bzip2' 'boost' 'boost-libs' 'protozero')
optdepends=('sparsehash: sparse-mem-table index map'
'gdal: convert OSM geometries into OGR geometries'
'geos: convert OSM geometries into GEOS geometries'
'proj: project OSM coordinates into spatial reference systems'
'doxygen: build Libosmium API documentation')
conflicts=('libosmium-git')
provides=('libosmium')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/osmcode/${pkgname}/archive/v${pkgver}.tar.gz")
build() {
mkdir -p "${srcdir}/${pkgname}-${pkgver}/build"
cd "${srcdir}/${pkgname}-${pkgver}/build"
cmake \
-DINSTALL_GDALCPP=ON \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX:PATH=/usr \
..
make
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}/build"
ctest
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}/build"
make DESTDIR="${pkgdir}" install
install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
sha256sums=('402247f7764bc20c061fa7d9fad15fc85459b7ce4f420274de78c94d05ddf260')
|