blob: 1bf0ac9e57e7088660459b0f8b6a7d3e93ecca47 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Vadim Yanitskiy <fixeria@osmocom.org>
# Contributor: Josef Miegl <josef@miegl.cz>
pkgname=libosmo-sigtran-git
pkgver=2.0.0.r0.g3d8f3b5
pkgrel=1
pkgdesc="Osmocom SIGTRAN (SCCP/SUA/M3UA) library as well as OsmoSTP"
url="https://osmocom.org/projects/libosmo-sccp"
arch=('i686' 'x86_64' 'aarch64' 'armv7h')
license=('GPL-2.0-or-later')
depends=('libosmocore-git' 'libosmo-netif-git' 'lksctp-tools' 'talloc')
makedepends=('git')
provides=("${pkgname%-git}=${pkgver}"
'libosmo-sigtran.so=10-64')
conflicts=("${pkgname%-git}"
'libosmo-sccp-git'
'libosmo-sccp')
replaces=('libosmo-sccp-git')
backup=('etc/osmocom/osmo-stp.cfg')
source=("git+https://gitea.osmocom.org/osmocom/${pkgname%-git}.git")
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${pkgname%-git}"
autoreconf -f -i
}
build() {
cd "${pkgname%-git}"
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var
make
}
check() {
cd "${pkgname%-git}"
make check
}
package() {
cd "${pkgname%-git}"
make DESTDIR=${pkgdir} install
}
# vim:set ts=2 sw=2 et:
|