blob: b171dbae25f4ba112e07110f80a128fd46029d45 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer: Václav Kubernát <sir.venceslas@gmail.com>
pkgname=libosmscout-git
pkgver=r8217.74095f1
pkgrel=1
arch=(x86_64)
url='https://github.com/Framstag/libosmscout'
license=(LGPL3 custom)
pkgdesc='A C++ library for offline map rendering, routing and location lookup based on OpenStreetMap data'
depends=(
glew
glfw-x11
glm
marisa
onetbb
freetype2
pango
zlib
protobuf
gcc-libs
libglvnd
abseil-cpp
cairo
glib2
libxml2
glibc
libpng
qt6-base
qt6-5compat
qt6-declarative
qt6-multimedia
qt6-positioning
qt6-svg
)
makedepends=(git meson ninja qt6-tools swig)
conflicts=(${pkgname%-git})
provides=(${pkgname%-git})
source=("git+https://github.com/Framstag/libosmscout"
'0001-dont-install-demos-and-tests.patch')
sha256sums=('SKIP'
'7228c3d78463504148d5808d642167519466eb4269b41db767924e9602bfbd78')
prepare() {
cd libosmscout
patch -Np1 -i ../0001-dont-install-demos-and-tests.patch
}
pkgver() {
cd libosmscout
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
build() {
cmake \
-S "$srcdir/${pkgname%-git}" \
-B "$srcdir/build" \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_BUILD_TYPE=Release \
-DOSMSCOUT_BUILD_DOC_API=OFF \
-DQT_VERSION_PREFERRED=6
cmake --build "$srcdir/build"
}
check() {
ctest --test-dir "$srcdir/build"
}
package() {
DESTDIR="$pkgdir" cmake --install "$srcdir/build"
install -Dm644 libosmscout/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgbase
}
|